build: convert main .gradle to kts

build.gradle

@@ -1,27 +0,0 @@
-plugins {
-    alias(libs.plugins.android.application) apply false
-    alias(libs.plugins.android.library) apply false
-    alias(libs.plugins.kotlin.android) apply false
-    alias(libs.plugins.kotlin.parcelize) apply false
-    alias(libs.plugins.ksp) apply false
-}
-
-wrapper {
-    distributionType = Wrapper.DistributionType.ALL
-}
-
-allprojects {
-    group = 'im.molly'
-
-    ext {
-        gitVersion = gitVersion()
-    }
-}
-
-task clean(type: Delete) {
-    delete rootProject.buildDir
-}
-
-static def gitVersion() {
-    return 'git describe --tags --always --first-parent'.execute().text.trim()
-}

build.gradle.kts

@@ -0,0 +1,17 @@
+plugins {
+    alias(libs.plugins.android.application) apply false
+    alias(libs.plugins.android.library) apply false
+    alias(libs.plugins.kotlin.android) apply false
+    alias(libs.plugins.kotlin.parcelize) apply false
+    alias(libs.plugins.ksp) apply false
+}
+
+allprojects {
+    group = "im.molly"
+}
+
+tasks {
+    wrapper {
+        distributionType = Wrapper.DistributionType.ALL
+    }
+}

settings.gradle

@@ -1,28 +0,0 @@
-pluginManagement {
-    repositories {
-        gradlePluginPortal()
-        google()
-        mavenCentral()
-    }
-}
-
-dependencyResolutionManagement {
-    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
-    repositories {
-        google()
-        mavenCentral()
-    }
-    versionCatalogs {
-        testLibs {
-            from(files('gradle/test-libs.versions.toml'))
-        }
-    }
-}
-
-includeProject(':lib', 'lib/android')
-includeProject(':demo', 'demo/android')
-
-def includeProject(String name, String filePath) {
-    include(name)
-    project(name).projectDir = file(filePath)
-}

settings.gradle.kts

@@ -0,0 +1,29 @@
+pluginManagement {
+    repositories {
+        gradlePluginPortal()
+        google()
+        mavenCentral()
+    }
+}
+
+dependencyResolutionManagement {
+    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
+    repositories {
+        google()
+        mavenCentral()
+    }
+    versionCatalogs {
+        create("testLibs") {
+            from(files("gradle/test-libs.versions.toml"))
+        }
+    }
+}
+
+includeProject("lib", "lib/android")
+includeProject("demo", "demo/android")
+
+fun includeProject(projectName: String, projectRoot: String) {
+    val projectId = ":$projectName"
+    include(projectId)
+    project(projectId).projectDir = file(projectRoot)
+}