terraform-provider: implement constellation_cluster resource (#2691)

* terraform: move module to legacy-directory

* constellation-lib: refactor service account marshalling

* terraform-provider: normalize Azure image URIs

* constellation-lib: refactor Kubeconfig endpoint rewriting

* terraform-provider: add conversion functions for AWS and GCP

* terraform-provider: implement `constellation_cluster` resource

* terraform-provider: refactor conversion

* terraform-provider: implement image and k8s upgrades

* terraform-provider: fix linter checks

* terraform-provider: refactor to bundle init & upgrade method

* constellation-lib: rewrite Kubeconfig endpoint in init

* terraform-provider: bind logger and dialer constructors to struct

* terraform-provider: move applier to function pointer

* terraform-provider: gcp conversion fixes

Signed-off-by: Moritz Sanft <58110325+msanft@users.noreply.github.com>

* terraform-provider: fix Azure UAMI input

* terraform-provider: rename Kubeconfig variable

* terraform-provider: tidy

* terraform-provider: regenerate docs

* constellation-lib: provide Kubeconfig in testing initserver

---------

Signed-off-by: Moritz Sanft <58110325+msanft@users.noreply.github.com>

terraform/legacy-module/gcp-constellation/main.tf

@@ -0,0 +1,69 @@
+locals {
+  region = substr(var.zone, 0, length(var.zone) - 2)
+}
+
+module "gcp_iam" {
+  source             = "../../infrastructure/iam/gcp"
+  project_id         = var.project
+  service_account_id = var.service_account_id
+  region             = local.region
+  zone               = var.zone
+}
+
+
+resource "null_resource" "ensure_yq" {
+  provisioner "local-exec" {
+    command = <<EOT
+         ../common/install-yq.sh
+    EOT
+  }
+  triggers = {
+    always_run = timestamp()
+  }
+}
+
+module "fetch_image" {
+  source              = "../common/fetch-image"
+  csp                 = "gcp"
+  attestation_variant = "gcp-sev-es"
+  image               = var.image
+  depends_on          = [null_resource.ensure_yq]
+}
+
+
+module "gcp" {
+  source          = "../../infrastructure/gcp"
+  project         = var.project
+  image_id        = module.fetch_image.image
+  name            = var.name
+  node_groups     = var.node_groups
+  region          = local.region
+  zone            = var.zone
+  debug           = var.debug
+  custom_endpoint = var.custom_endpoint
+}
+
+module "constellation" {
+  source               = "../constellation-cluster"
+  csp                  = "gcp"
+  debug                = var.debug
+  name                 = var.name
+  image                = var.image
+  microservice_version = var.microservice_version
+  kubernetes_version   = var.kubernetes_version
+  uid                  = module.gcp.uid
+  clusterEndpoint      = module.gcp.out_of_cluster_endpoint
+  inClusterEndpoint    = module.gcp.in_cluster_endpoint
+  initSecretHash       = module.gcp.initSecret
+  ipCidrNode           = module.gcp.ip_cidr_nodes
+  apiServerCertSANs    = module.gcp.api_server_cert_sans
+  node_groups          = var.node_groups
+  gcp_config = {
+    region            = local.region
+    zone              = var.zone
+    project           = var.project
+    ipCidrPod         = module.gcp.ip_cidr_pods
+    serviceAccountKey = module.gcp_iam.sa_key
+  }
+  depends_on = [module.gcp, null_resource.ensure_yq]
+}

terraform/legacy-module/gcp-constellation/variables.tf

@@ -0,0 +1,72 @@
+variable "name" {
+  type        = string
+  description = "Name of the Constellation cluster."
+}
+
+variable "project" {
+  type        = string
+  description = "The project ID to deploy the cluster to."
+}
+
+variable "service_account_id" {
+  type        = string
+  description = "The service account ID to use for the cluster."
+}
+
+variable "image" {
+  type        = string
+  description = "Node image reference or semantic release version. When not set, the latest default version will be used."
+  default     = "@@CONSTELLATION_VERSION@@"
+}
+
+variable "microservice_version" {
+  type        = string
+  description = "Microservice version. When not set, the latest default version will be used."
+  default     = ""
+}
+
+variable "kubernetes_version" {
+  type        = string
+  description = "Kubernetes version. When not set, the latest default version will be used."
+  default     = ""
+}
+
+variable "node_groups" {
+  type = map(object({
+    role          = string
+    initial_count = optional(number)
+    instance_type = string
+    disk_size     = number
+    disk_type     = string
+    zone          = string
+  }))
+  description = "A map of node group names to node group configurations."
+  validation {
+    condition     = can([for group in var.node_groups : group.role == "control-plane" || group.role == "worker"])
+    error_message = "The role has to be 'control-plane' or 'worker'."
+  }
+}
+
+variable "zone" {
+  type        = string
+  description = "The availability zone name to create the cluster in."
+}
+
+variable "debug" {
+  type        = bool
+  default     = false
+  description = "DON'T USE IN PRODUCTION: Enable debug mode and allow the use of debug images."
+}
+
+
+variable "custom_endpoint" {
+  type        = string
+  default     = ""
+  description = "Custom endpoint (DNS Name) to use for the Constellation API server. If not set, the default endpoint will be used."
+}
+
+variable "internal_load_balancer" {
+  type        = bool
+  default     = false
+  description = "Use an internal load balancer."
+}