mirror of
https://github.com/RetroShare/RetroShare.git
synced 2024-12-25 15:39:27 -05:00
7ad337c8d2
qmake file add jsonapi-generator target to compile JSON API generator qmake files add rs_jsonapi CONFIG option to enable/disable JSON API at compile time RsTypeSerializer pass down same serialization flags when creating new context for nested objects serial job RsGxsChannels expose a few methods through JSON API as example Derive a few GXS types (RsGxsChannelGroup, RsGxsChannelPost, RsGxsFile, RsMsgMetaData) from RsSerializables so they can be used for the JSON API Create RsGenericSerializer::SERIALIZATION_FLAG_YIELDING so JSON objects that miss some fields can be still deserialized, this improve API usability SerializeContext offer friendly constructor with default paramethers Add restbed 4.6 library as git submodule as most systems doesn't have it yet Add a bit of documentation about JSON API into jsonapi-generator/README.adoc Add JsonApiServer class to expose the JSON API via HTTP protocol
93 lines
2.7 KiB
Prolog
93 lines
2.7 KiB
Prolog
!include("retroshare.pri"): error("Could not include file retroshare.pri")
|
|
|
|
TEMPLATE = subdirs
|
|
|
|
SUBDIRS += openpgpsdk
|
|
openpgpsdk.file = openpgpsdk/src/openpgpsdk.pro
|
|
|
|
retrotor {
|
|
libretroshare.depends = openpgpsdk
|
|
} else {
|
|
SUBDIRS += libbitdht
|
|
libbitdht.file = libbitdht/src/libbitdht.pro
|
|
libretroshare.depends = openpgpsdk libbitdht
|
|
}
|
|
|
|
rs_jsonapi {
|
|
SUBDIRS += jsonapi-generator
|
|
jsonapi-generator.file = jsonapi-generator/src/jsonapi-generator.pro
|
|
libretroshare.depends += jsonapi-generator
|
|
}
|
|
|
|
SUBDIRS += libretroshare
|
|
libretroshare.file = libretroshare/src/libretroshare.pro
|
|
|
|
SUBDIRS += libresapi
|
|
libresapi.file = libresapi/src/libresapi.pro
|
|
libresapi.depends = libretroshare
|
|
|
|
retroshare_gui {
|
|
SUBDIRS += retroshare_gui
|
|
retroshare_gui.file = retroshare-gui/src/retroshare-gui.pro
|
|
retroshare_gui.depends = libretroshare libresapi
|
|
retroshare_gui.target = retroshare_gui
|
|
}
|
|
|
|
retrotor {
|
|
} else {
|
|
retroshare_nogui {
|
|
SUBDIRS += retroshare_nogui
|
|
retroshare_nogui.file = retroshare-nogui/src/retroshare-nogui.pro
|
|
retroshare_nogui.depends = libretroshare libresapi
|
|
retroshare_nogui.target = retroshare_nogui
|
|
}
|
|
}
|
|
|
|
retroshare_android_service {
|
|
SUBDIRS += retroshare_android_service
|
|
retroshare_android_service.file = retroshare-android-service/src/retroshare-android-service.pro
|
|
retroshare_android_service.depends = libresapi
|
|
retroshare_android_service.target = retroshare_android_service
|
|
}
|
|
|
|
retroshare_android_notify_service {
|
|
SUBDIRS += retroshare_android_notify_service
|
|
retroshare_android_notify_service.file = retroshare-android-notify-service/src/retroshare-android-notify-service.pro
|
|
retroshare_android_notify_service.depends = retroshare_android_service
|
|
retroshare_android_notify_service.target = retroshare_android_notify_service
|
|
}
|
|
|
|
retroshare_qml_app {
|
|
SUBDIRS += retroshare_qml_app
|
|
retroshare_qml_app.file = retroshare-qml-app/src/retroshare-qml-app.pro
|
|
retroshare_qml_app.depends = retroshare_android_service
|
|
retroshare_qml_app.target = retroshare_qml_app
|
|
|
|
android-g++ {
|
|
retroshare_qml_app.depends += retroshare_android_notify_service
|
|
}
|
|
}
|
|
|
|
retroshare_plugins {
|
|
SUBDIRS += plugins
|
|
plugins.file = plugins/plugins.pro
|
|
plugins.depends = retroshare_gui
|
|
plugins.target = plugins
|
|
}
|
|
|
|
wikipoos {
|
|
SUBDIRS += pegmarkdown
|
|
pegmarkdown.file = supportlibs/pegmarkdown/pegmarkdown.pro
|
|
retroshare_gui.depends += pegmarkdown
|
|
}
|
|
|
|
tests {
|
|
SUBDIRS += librssimulator
|
|
librssimulator.file = tests/librssimulator/librssimulator.pro
|
|
|
|
SUBDIRS += unittests
|
|
unittests.file = tests/unittests/unittests.pro
|
|
unittests.depends = libretroshare librssimulator
|
|
unittests.target = unittests
|
|
}
|