mirror of
https://github.com/RetroShare/RetroShare.git
synced 2024-12-24 23:19:29 -05:00
5aaf3e66f7
The icons and desktop file in the data directory are shared between linux distributions so they shouldn't be in the build_scripts directory. The redhat build now makes use of "make install" and relocatable plugins dir.
48 lines
1.5 KiB
Prolog
48 lines
1.5 KiB
Prolog
TEMPLATE = subdirs
|
|
|
|
CONFIG += ordered
|
|
|
|
SUBDIRS += \
|
|
openpgpsdk/src/openpgpsdk.pro \
|
|
supportlibs/pegmarkdown/pegmarkdown.pro \
|
|
libbitdht/src/libbitdht.pro \
|
|
libretroshare/src/libretroshare.pro \
|
|
libresapi/src/libresapi.pro \
|
|
retroshare-gui/src/retroshare-gui.pro \
|
|
retroshare-nogui/src/retroshare-nogui.pro \
|
|
plugins/plugins.pro
|
|
|
|
unix {
|
|
isEmpty(PREFIX) { PREFIX = /usr }
|
|
isEmpty(INC_DIR) { INC_DIR = "$${PREFIX}/include/retroshare06" }
|
|
isEmpty(LIB_DIR) { LIB_DIR = "$${PREFIX}/lib" }
|
|
isEmpty(DATA_DIR) { DATA_DIR = "$${PREFIX}/share/RetroShare06" }
|
|
|
|
icon_files.path = "$${PREFIX}/share/icons/hicolor"
|
|
icon_files.files = data/24x24
|
|
icon_files.files += data/48x48
|
|
icon_files.files += data/64x64
|
|
icon_files.files += data/128x128
|
|
INSTALLS += icon_files
|
|
|
|
desktop_files.path = "$${PREFIX}/share/applications"
|
|
desktop_files.files = data/retroshare06.desktop
|
|
INSTALLS += desktop_files
|
|
|
|
pixmap_files.path = "$${PREFIX}/share/pixmaps"
|
|
pixmap_files.files = data/retroshare06.xpm
|
|
INSTALLS += pixmap_files
|
|
|
|
data_files.path = "$${DATA_DIR}"
|
|
data_files.files = libbitdht/src/bitdht/bdboot.txt
|
|
INSTALLS += data_files
|
|
|
|
webui_files.path = "$${DATA_DIR}/webui"
|
|
webui_files.files = libresapi/src/webfiles/*
|
|
INSTALLS += webui_files
|
|
|
|
webui_img_files.path = "$${DATA_DIR}/webui/img"
|
|
webui_img_files.files = retroshare-gui/src/gui/images/logo/logo_splash.png
|
|
INSTALLS += webui_img_files
|
|
}
|