Use MSYS2 to build external libraries for Windows compile

build_scripts/Windows/env/env-msys2.bat

@@ -0,0 +1,39 @@
+:: Usage:
+:: call env-msys2.bat [reinstall|clean]
+
+:: Initialize environment
+call "%~dp0env.bat"
+if errorlevel 1 goto error_env
+
+rem openssl x86 doesn't compile with mingw64 x64
+:: Get gcc versions
+call "%ToolsPath%\get-gcc-version.bat" GCCVersion GCCArchitecture
+if "%GCCVersion%"=="" %cecho% error "Cannot get gcc version." & exit /B 1
+if "%GCCArchitecture%"=="" %cecho% error "Cannot get gcc architecture." & exit /B 1
+
+rem IF DEFINED ProgramFiles(x86) (
+if "%GCCArchitecture%"=="x64" (
+	:: x64
+	set MSYS2Architecture=x86_64
+	set MSYS2Base=64
+) else (
+	:: x86
+	set MSYS2Architecture=i686
+	set MSYS2Base=32
+)
+
+set EnvMSYS2Path=%EnvRootPath%\msys2
+
+call "%~dp0tools\prepare-msys2.bat" %1
+if errorlevel 1 exit /B %ERRORLEVEL%
+
+set EnvMSYS2SH=%EnvMSYS2Path%\msys%MSYS2Base%\usr\bin\sh.exe
+if not exist "%EnvMSYS2SH%" if errorlevel 1 goto error_env
+
+set EnvMSYS2Cmd="%EnvMSYS2SH%" -lc
+
+exit /B 0
+
+:error_env
+echo Failed to initialize environment.
+exit /B 1

build_scripts/Windows/env/env.bat

@@ -27,7 +27,7 @@ call "%~dp0tools\prepare-tools.bat"
 if errorlevel 1 exit /B %ERRORLEVEL%
 
 :: Add MinGit to PATH
-set PATH=%EnvToolsPath%\MinGit\cmd;%PATH%
+set PATH=%EnvToolsPath%\MinGit\cmd;%EnvToolsPath%\cmake\bin;%PATH%
 set HOME=%EnvToolsPath%\MinGit\home
 
 exit /B 0

build_scripts/Windows/env/tools/prepare-msys2.bat

@@ -0,0 +1,83 @@
+:: Usage:
+:: call prepare-msys2.bat [reinstall|clean]
+
+setlocal enabledelayedexpansion
+
+if "%EnvMSYS2Path%"=="" exit /B 1
+if "%MSYS2Architecture%"=="" exit /B 1
+if "%MSYS2Base%"=="" exit /B 1
+if not exist "%EnvRootPath%"=="" exit /B 1
+
+copy "%~dp0root\update-msys2.bat" "%EnvRootPath%" >nul
+
+if "%~1"=="clean" (
+	%cecho% info "Clean MSYS2"
+	call "%ToolsPath%\remove-dir.bat" "%EnvMSYS2Path%"
+	goto exit
+)
+
+if exist "%EnvMSYS2Path%\msys%MSYS2Base%\usr\bin\pacman.exe" (
+	if "%~1"=="reinstall" (
+		choice /M "Found existing MSYS2 version. Do you want to proceed?"
+		if !ERRORLEVEL!==2 goto exit
+	) else (
+		goto exit
+	)
+)
+
+set MSYS2Install=msys2-base-%MSYS2Architecture%-20190524.tar.xz
+set MSYS2Url=http://sourceforge.net/projects/msys2/files/Base/%MSYS2Architecture%/%MSYS2Install%/download
+set CMakeInstall=cmake-3.1.0-win32-x86.zip
+set CMakeUrl=http://www.cmake.org/files/v3.1/%CMakeInstall%
+set CMakeUnpackPath=%EnvMSYS2Path%\msys%MSYS2Base%
+
+%cecho% info "Remove previous MSYS2 version"
+call "%ToolsPath%\remove-dir.bat" "%EnvMSYS2Path%\msys%MSYS2Base%"
+
+%cecho% info "Download installation files"
+if not exist "%EnvDownloadPath%\%MSYS2Install%" call "%ToolsPath%\download-file.bat" "%MSYS2Url%" "%EnvDownloadPath%\%MSYS2Install%"
+if not exist "%EnvDownloadPath%\%MSYS2Install%" %cecho% error "Cannot download MSYS" & goto error
+
+if not exist "%EnvDownloadPath%\%CMakeInstall%" call "%ToolsPath%\download-file.bat" "%CMakeUrl%" "%EnvDownloadPath%\%CMakeInstall%"
+if not exist "%EnvDownloadPath%\%CMakeInstall%" %cecho% error "Cannot download CMake" & goto error
+
+%cecho% info "Unpack MSYS2"
+"%EnvSevenZipExe%" x -so "%EnvDownloadPath%\%MSYS2Install%" | "%EnvSevenZipExe%" x -y -si -ttar -o"%EnvMSYS2Path%"
+
+%cecho% info "Unpack CMake"
+"%EnvSevenZipExe%" x -o"%CMakeUnpackPath%" "%EnvDownloadPath%\%CMakeInstall%"
+
+%cecho% info "Install CMake"
+set CMakeVersion=
+for /D %%F in (%CMakeUnpackPath%\cmake*) do set CMakeVersion=%%~nxF
+if "%CMakeVersion%"=="" %cecho% error "CMake version not found." & goto :exit
+%cecho% info "Found CMake version %CMakeVersion%"
+
+set FoundProfile=
+for /f "tokens=3" %%F in ('find /c /i "%CMakeVersion%" "%EnvMSYS2Path%\msys%MSYS2Base%\etc\profile"') do set FoundProfile=%%F
+
+if "%FoundProfile%"=="0" (
+	echo export PATH="${PATH}:/%CMakeVersion%/bin">>"%EnvMSYS2Path%\msys%MSYS2Base%\etc\profile"
+)
+
+set MSYS2SH=%EnvMSYS2Path%\msys%MSYS2Base%\usr\bin\sh
+
+%cecho% info "Update keyring"
+"%MSYS2SH%" -lc "curl -O http://repo.msys2.org/msys/x86_64/msys2-keyring-r21.b39fb11-1-any.pkg.tar.xz"
+"%MSYS2SH%" -lc "pacman --noconfirm -U msys2-keyring-r21.b39fb11-1-any.pkg.tar.xz"
+
+%cecho% info "Initialize MSYS2"
+"%MSYS2SH%" -lc "pacman -Sy"
+"%MSYS2SH%" -lc "pacman --noconfirm --needed -S bash pacman pacman-mirrors msys2-runtime"
+
+call "%EnvMSYS2Path%\msys%MSYS2Base%\autorebase.bat"
+call "%EnvRootPath%\update-msys2.bat"
+call "%EnvRootPath%\update-msys2.bat"
+
+:exit
+endlocal
+exit /B 0
+
+:error
+endlocal
+exit /B 1

build_scripts/Windows/env/tools/prepare-tools.bat

@@ -24,6 +24,10 @@ set MinGitUrl=https://github.com/git-for-windows/git/releases/download/v2.28.0.w
 set MinGitInstallPath=%EnvToolsPath%\MinGit
 set SigcheckInstall=Sigcheck.zip
 set SigcheckUrl=https://download.sysinternals.com/files/%SigcheckInstall%
+set CMakeVersion=cmake-3.1.0-win32-x86
+set CMakeInstall=%CMakeVersion%.zip
+set CMakeUrl=http://www.cmake.org/files/v3.1/%CMakeInstall%
+set CMakeInstallPath=%EnvToolsPath%\cmake
 
 if not exist "%EnvToolsPath%\wget.exe" (
 	echo Download Wget installation
@@ -185,6 +189,25 @@ if not exist "%EnvToolsPath%\sigcheck.exe" (
 	"%EnvSevenZipExe%" x -o"%EnvToolsPath%" "%EnvDownloadPath%\%SigcheckInstall%" sigcheck.exe
 )
 
+if not exist "%EnvDownloadPath%\%CMakeInstall%" call "%ToolsPath%\remove-dir.bat" "%CMakeInstallPath%"
+if not exist "%CMakeInstallPath%\bin\cmake.exe" (
+	%cecho% info "Download CMake installation"
+
+	if exist "%CMakeInstallPath%" call "%ToolsPath%\remove-dir.bat" "%CMakeInstallPath%"
+
+	mkdir "%EnvTempPath%"
+
+	if not exist "%EnvDownloadPath%\%CMakeInstall%" call "%ToolsPath%\download-file.bat" "%CMakeUrl%" "%EnvDownloadPath%\%CMakeInstall%"
+	if not exist "%EnvDownloadPath%\%CMakeInstall%" %cecho% error "Cannot download CMake installation" & goto error
+
+	%cecho% info "Unpack CMake"
+	"%EnvSevenZipExe%" x -o"%EnvTempPath%" "%EnvDownloadPath%\%CMakeInstall%"
+
+	move "%EnvTempPath%\%CMakeVersion%" "%CMakeInstallPath%"
+
+	call "%ToolsPath%\remove-dir.bat" "%EnvTempPath%"
+)
+
 :exit
 endlocal
 exit /B 0

build_scripts/Windows/env/tools/root/update-msys2.bat

@@ -0,0 +1,19 @@
+@echo off
+
+setlocal
+
+if exist "%~dp0msys2\msys32" call :update 32
+if exist "%~dp0msys2\msys64" call :update 64
+
+goto :EOF
+
+:update
+set MSYSSH=%~dp0msys2\msys%~1\usr\bin\sh
+
+echo Update MSYS2 %~1
+"%MSYSSH%" -lc "pacman -Sy"
+"%MSYSSH%" -lc "pacman --noconfirm -Su"
+
+:exit
+endlocal
+goto :EOF