Use explicit dependencies instead of CONFIG += ordered

Makes inter-dependencies clearer and allows parallel build of
independent libs on multi-core systems, e.g. with:
$ make -j4

RetroShare.pro

@@ -1,16 +1,35 @@
 TEMPLATE = subdirs
 
-CONFIG += ordered
-
 SUBDIRS += \
-        openpgpsdk/src/openpgpsdk.pro \
+        openpgpsdk \
-        supportlibs/pegmarkdown/pegmarkdown.pro \
+        libbitdht \
-        libbitdht/src/libbitdht.pro \
+        libretroshare \
-        libretroshare/src/libretroshare.pro \
+        libresapi \
-		libresapi/src/libresapi.pro	\
+        pegmarkdown \
-        retroshare-gui/src/retroshare-gui.pro \
+        retroshare_gui \
-        retroshare-nogui/src/retroshare-nogui.pro \
+        retroshare_nogui \
-        plugins/plugins.pro
+        plugins
+
+openpgpsdk.file = openpgpsdk/src/openpgpsdk.pro
+
+libbitdht.file = libbitdht/src/libbitdht.pro
+
+libretroshare.file = libretroshare/src/libretroshare.pro
+libretroshare.depends = openpgpsdk libbitdht
+
+libresapi.file = libresapi/src/libresapi.pro
+libresapi.depends = libretroshare
+
+pegmarkdown.file = supportlibs/pegmarkdown/pegmarkdown.pro
+
+retroshare_gui.file = retroshare-gui/src/retroshare-gui.pro
+retroshare_gui.depends = libretroshare libresapi pegmarkdown
+
+retroshare_nogui.file = retroshare-nogui/src/retroshare-nogui.pro
+retroshare_nogui.depends = libretroshare libresapi
+
+plugins.file = plugins/plugins.pro
+plugins.depends = retroshare_gui
 
 unix {
 	isEmpty(PREFIX)   { PREFIX = /usr }